Программа "Календарь" (определение числа дней в месяце) рассматривает ячейку 01 как номер месяца и определяет количество дней в этом месяце.

Приводится два варианта решения. Первый - более простой - хранит количество дней в месяце в виде массива (последовательности чисел 31, 28, 31, 30, ...), и программа просто извлекает его элемент с нужным номером. Второй - логический - более сложный, но зато более короткий. Если к программе применимо понятие красоты (а по-моему, это так), то второй вариант несомненно красивее!

Вариант 1.

В памяти, начиная с ячейки 03 хранится 12 чисел, соответствующих количеству дней в каждом месяце. Программа к исходному номеру месяца прибавляет число на единицу меньше, т.е. 2 (дело в том, что месяцы нумеруются с 1, поэтому без этой коррекции для января получалось бы 3 + 1 = 4, для февраля 3 + 2 = 5 и т.д., т.е со сдвигом как раз на 1!) Полученное число записывается "внутрь" программы в качестве команды. Поскольку нулевому коду операции соответствует извлечение содержимого ячейки на сумматор, то сформированная команда достанет нужный элемент массива.

Например, для заданного в таблице случая n = 6 (июнь), получим 002 + 006 = 008, т.е. фактически команду 0 (первая цифра) извлечения из памяти содежимого ячейки 08 (две последние цифры). Проверьте и убедитесь, что в этой ячейке лежит информация именно для июня.

адрес	код	мнемоника	комментарии
n:			n - номер месяца!
01	006	dw 6	исходная переменная n, для примера взято значение 6
a0:			адрес начала массива (a0 = days - 1)
02	002	dw a0	(потребуется для формирования команды)
days:			массив количества дней (dw 31, 28, 31, 30 ...)
03	01F	dw 31	первый элемент: число дней в январе
04	01C	dw 28	второй элемент: число дней в феврале
05	01F	dw 31	третий элемент: число дней в марте
06	01E	dw 30	четвертый элемент: число дней в апреле
07	01F	dw 31	(май)
08	01E	dw 30	(июнь)
09	01F	dw 31	(июль)
0A	01F	dw 31	(август)
0B	01E	dw 30	(сентябрь)
0C	01F	dw 31	(октябрь)
0D	01E	dw 30	(ноябрь)
0E	01F	dw 31	двеннадцатый элемент - количество дней в декабре
begin:			начало программы
0F	001	lda (n)	извлечь n
10	A02	add (a0)	прибавить адрес начала массива
11	112	sta (command)	записать полученное число как команду
command:			формируемая команда
12	00x	lda (00x)	(команда извлечения нужного элемента; например, для июня 00x = 002 + 006 = 008)
13	C00	iprt	вывести результат на экран
14	F00	hlt	останов (стоп)

Вариант 2.

Посмотрим внимательно на подготовленную ниже таблицу, в которой для каждого месяца выписан его двоичный номер и количество дней:

месяц	янв.	фев.	март	апр.	май	июнь	июль	авг.	сен.	окт.	нояб.	дек.
дней	31	28	31	30	31	30	31	31	30	31	30	31
номер2	0001	0010	0011	0100	0101	0110	0111	1000	1001	1010	1011	1100

Если не обращать внимания на февраль, то можно заметить четкую связь между количеством дней в месяце и состоянием старшего (3-го) и младшего (0-го) битов его номера, а именно: в месяце 31 день, если эти биты различны и 30 - если одинаковы! (Проверьте, что это так.) Воспользуемся этим фактом при написании программы.

Прежде всего отметим, что для сравнения битов существует специальная логическая операция, которая называется исключающее ИЛИ. К сожалению, у "Малютки" она отсутствует, поэтому придется ее заменить на сложение битов с игнорированием возникающего переноса (чтобы сделать это, достаточно в результате суммирования стирать все биты, кроме 0-го), т.е.:

0 + 0 = 0

0 + 1 = 1

1 + 0 = 1

1 + 1 = 0

Таким образом, остается вычислить по указанным правилам сумму 3-го и 0-го битов и к результату просто прибавить 30!

Разумеется для февраля придется количество дней рассчитывать отдельно. Если бы не это "досадное исключение", программа была бы еще короче!

адрес	код	мнемоника	комментарии
n:			n - номер месяца!
01	006	dw 6	исходная переменная n, для примера взято значение 6
02	802	dw -2	для февраля (константа min2)
03	001	dw 1	для выделения младшего бита (константа mask)
04	01E	dw 30	количество дней (константа day0)
begin:			начало программы
05	001	lda (n)	извлечь n
06	A02	add (min2)	n - 2 (сравнение с февралем)
07	E0F	jz printfeb	переход, если февраль (к 0F)
08	001	lda (n)	извлечь n       (xxxx xxxx Bxxx)
09	310	sar	сдвиг вправо (xxxx xxxx xBxx)
0A	310	sar	сдвиг вправо (xxxx xxxx xxBx)
0B	310	sar	сдвиг вправо (xxxx xxxx xxxB - 3-й бит попал в 0-й)
0C	A01	add (n)	сложить этот бит с 0-м у исходного числа
0D	803	and (mask)	оставить только младший бит
0E	410	jmp dalee	обход ветки февраля (к 10)
printfeb:			для февраля взять -2, т.к. 28 = 30 - 2
0F	002	lda (min2)	поместить в СМ константу -2
dalee:
10	A04	add (day0)	СМ + 30 - получим количество дней
11	C00	iprt	вывести результат на экран
12	F00	hlt	останов (стоп)

Я надеюсь, что при реализации второго варианта Вы, как и я, получили определенное интеллектуальное удовлетворение от подтверждения на практике довольно абстрактных рассуждений о битах!